👀 Unison at a glance

This document contains code snippets with a minimum of exposition. Links are provided throughout to more comprehensive docs sections. If you haven't downloaded the UCM, you might want to do that first. 😎

Hello World

Write your Unison code in any .u suffixed "scratch" file.

The classic helloWorld program performs console interactions via the IO ability. Read about how abilities model effects in Unison.

usingAbilitiesPt1.helloWorld : '{IO, Exception} ()

usingAbilitiesPt1.helloWorld : '{IO, Exception} ()
usingAbilitiesPt1.helloWorld _ = printLine "Hello World!"

Execute the entry point to your program with the run UCM command.

scratch/main> project.create hello-world
hello-world/main> run helloWorld

Or add your helloWorld program to the codebase and run it by packaging it up in a binary executable!

hello-world/main> add
hello-world/main> compile helloWorld helloFile

This will produce an executable file called helloFile.uc in the same directory as the codebase. You can then start your program in your terminal.

$ ucm run.compiled helloFile.uc

📚Learn more about executing Unison programs

Basic functions

The following introduces a function double with one parameter. Unison conventions for defining functions are detailed here

glance.double : Nat -> Nat

glance.double : Nat -> Nat
glance.double x =
  use Nat *
  x * 2

> double 4

The > in a scratch file runs the double function in a watch expression.

📚The Unison tour walks through watch expressions and other workflow features

Delayed computation syntax

There are two ways to indicate that a computation is delayed in Unison. The first is the do keyword:

main : '{IO,Exception}()
main = do
 printLine "`do` is commonly seen at the start of an indented block of code"

The ' symbol is the second syntax option for introducing a thunk.

Stream.toList (Stream.map Nat.increment do emit 1)⧨[2]

Calling, or "forcing" the delayed computation also has two options. Prepend ! to the deplayed comptuation or append () to call it.

streamList : '[Nat]

streamList : '[Nat]
streamList = toDelayedList do Stream.range 10 15

!streamList

streamList()

A more detailed look at delayed computations

List literals

Square brackets introduce a Unison list.

[0, 1, 2, 3] List.++ [4, 5]⧨[0, 1, 2, 3, 4, 5]

The List.++ is our operator for list concatenation.

use List +: :+
head = 1 +: [2, 3, 4]
head :+ 5⧨[1, 2, 3, 4, 5]

A variety of list patterns are available for lists.

📚Learn more about common collection types in Unison

List transformations

Nat.range 0 10
  |> List.map (x -> x Nat.* 100)
  |> List.filter (const true)
  |> List.foldLeft (Nat.+) 0⧨4500

The |> operator is a "pipe" which passes the result of executing the expression on the left as an argument to function on right.

The parenthesized x -> x Nat.* 100 argument to List.map is an example of lambdas in Unison.

📚Learn more about operators like |>

if/else and pattern matching

The expression below is written with both if then and else syntax and with pattern matching syntax

use Nat mod
isEven1 num =
  if mod num 2 === 0 then true else false
isEven2 num = match num with
  n | mod n 2 === 0 -> true
  _ -> false

Unison's pattern matching features include variable binding, pattern guards (separated by |), and as-patterns (indicated with an @).

match Some 12 with
  Optional.None -> "none"
  Some n| Nat.isEven n  -> "n is a variable and | is a pattern guard"
  opt@(Some n) -> "opt binds to the entire optional value"⧨"n is a variable and | is a pattern guard"

The cases syntax can take the place of a full match ... with expression.

foo n = match n with
  0 -> "zero"
  _ -> "not zero"
foo 0

foo = cases
  0 -> "zero"
  _ -> "not zero"
foo 0⧨"zero"

Type declarations

A unison data type with uniqueness determined by its name:

type LivingThings

type LivingThings
  = docs.glance.LivingThings.Animal
  | docs.glance.LivingThings.Plant
  | docs.glance.LivingThings.Fungi
  | docs.glance.LivingThings.Protists
  | docs.glance.LivingThings.Monera

A recursive Tree data type with a single type parameter:

structural type glance.Tree a

structural type glance.Tree a
  = docs.glance.Tree.Empty
  | docs.glance.Tree.Node a (glance.Tree a) (glance.Tree a)

The structural keyword means that types defined with the same structure are identical.

More on data types and the difference between structural and unique.

Record types allow you to name the fields of your type.

unique type Pet = {
   age : Nat,
   species : Text,
   foodPreferences : [Text]
}

Creating a record type generates a series of helper methods to access and update the fields of the data type.

myProject/main> add Pet

 ⍟ I've added these definitions:

     unique type Pet
     Pet.age                    : Pet -> Nat
     Pet.age.modify             : (Nat ->{g} Nat) -> Pet ->{g} Pet
     Pet.age.set                : Nat -> Pet -> Pet

Record type syntax in depth

Exception handling

nonZero : Nat ->{Exception} Nat

nonZero : Nat ->{Exception} Nat
nonZero = cases
  n
    | n Nat.== 0  ->
      Exception.raise (Generic.failure "Zero was found" n)
    | otherwise   -> n

catch do nonZero 0⧨Either.Left (Failure (typeLink Generic) "Zero was found" (Any 0))

An exception is "raised" with the Exception ability and "caught" with a handler.

Our error handling with abilities doc describes this pattern and more error types in detail.

Using abilities

Abilities are used for effect management in Unison.

getRandomElem : [a] ->{Abort, Random} a

getRandomElem : [a] ->{Abort, Random} a
getRandomElem list =
  index = Random.natIn 0 (List.size list)
  List.at! index list

toOptional! do splitmix 42 do getRandomElem [1, 2, 3, 4, 5]⧨Some 5

This plucks a random element from the list by its index with Random.natIn, a function using the Random ability. If the index is not present in the list, it uses the Abort ability to halt execution.

splitmix and toOptional! are examples of ability handlers.

Distributed computations

Distributed computations can be expressed in the Unison language itself through the Remote ability. Read about the Remote ability and its features

distributed : Seq k Nat ->{Remote} Nat

distributed : Seq k Nat ->{Remote} Nat
distributed dseq =
  use Nat + ==
  dseq
    |> Seq.map (x -> x + 1)
    |> Seq.filter (x -> Nat.mod x 7 == 0)
    |> Seq.reduce 0 (+)

This simple map/reduce code can operate over a distributed sequence, where the data may live in many different nodes in a cluster. This distributed computation use case has been fleshed out in an article.

Issuing an http request

Pull the library from Unison Share. with the lib.install command.

myProject/main> lib.install @unison/http

exampleGet : '{IO, Exception} HttpResponse

exampleGet : '{IO, Exception} HttpResponse
exampleGet _ =
  uri =
    net.URI.parse "https://share.unison-lang.org/@unison/httpclient"
  req = do Http.get uri
  Http.run req

The first part of this code uses data constructors from the http library to create a full uri out of an authority and path. The request is handled by passing it to the Http handler.

The http library has great docs!

Basic file operations

readFileUtf8       : FilePath ->{IO, Exception} Text
FilePath.writeFile : FilePath -> Bytes ->{IO, Exception} ()
renameFile         : FilePath -> FilePath ->{IO, Exception} ()

Our standard library has a number of helpful File operations built in. They're located under the FilePath and Handle namespaces.

Concurrency primitives

Concurrency primitives like MVar, TVar, and STM are built into the base library. TVar and STM make it easy to write lock-free concurrent mutable data structures. For instance, here’s a simple lock-free queue implementation and a few helper functions:

type TQueue a

type TQueue a
  = lib.base.IO.concurrent.STM.TQueue.TQueue (TVar [a]) (TVar Nat)

enqueue : a -> TQueue a ->{STM} ()

enqueue : a -> TQueue a ->{STM} ()
enqueue a = cases
  TQueue elems _ -> TVar.modify elems (es -> a List.+: es)

dequeue : TQueue a ->{STM} a

dequeue : TQueue a ->{STM} a
dequeue tq = match tryDequeue tq with
  Optional.None -> retry()
  Some a        -> a

The block introduced by STM.atomically below ensures that no one can access state of the queue until after the actions in the block have taken place.

queueExample : '{IO, Exception} ()

queueExample : '{IO, Exception} ()
queueExample _ =
  runQueue : '{STM} Nat
  runQueue _ =
    queue = TQueue.fromList [1, 2, 3, 4, 5]
    enqueue 6 queue
    dequeue queue
    dequeue queue
  result = STM.atomically runQueue
  printLine (Nat.toText result)

run

myProgram : '{IO, Exception} ()
myProgram = '(printLine "Hello World")

myProgramWithArgs : '{IO, Exception} ()
myProgramWithArgs = 'let
  printLine ("Hello " ++ Optional.getOrElse "World" (List.head !getArgs) ++ "!")

scratch/main> run myProgram
scratch/main> run myProgramWithArgs Rebecca

The run command is used to evaluate terms that require the IO ability within ucm. A program that performs IO cannot be evaluated in a watch expression but can be executed with run.

Run takes a delayed computation and performs !myProgram, where myProgram is searched for in the most recent typechecked file, or in the codebase. The function provided to the run command can return any type, and may perform the IO and Exception abilities.

Any arguments following the run command will be passed as program arguments.

add

myProject/main> add

myProject/main> add myNewTerm

Adds all the definitions from the most recently typechecked file to the codebase.

FAQ about the add command

I got an error about "these definitions failed" on add

This message happens when some of the definitions couldn't be added to the codebase. UCM shows a table of definitions along with the reason why they didn't succeed, like this:

x These definitions failed:

Reason
needs update   myFunction : Doc

Here's what these reasons mean:

needs update: The scratch file has a definition with the same name as an existing definition. Doing update instead of add will turn this failure into a successful update.
conflicted: The file has a definition whose name is currently conflicted. Resolving the conflict and then trying an update again will turn this into a successful update.
term/ctor collision: A definition with the same name as an existing constructor for some data type. Rename your definition or the data type before trying again to add or update.
ctor/term collision: A type defined in the file has a constructor that's named the same as an existing term. Rename that term or your constructor before trying again to add or update.
needs alias: A definition in the file already has another name. You can use the alias.term or alias.type commands to create new names for existing definitions.
blocked: This definition couldn't be added because it dependended on another definition in the file that had a failed status.
extra dependency: This definition was added because it was a dependency of a definition explicitly selected.

I want to undo a partially completed add where some of the definitions failed

You can use the undo command in the case of an undesired partially completed add.

Operators

Operators are functions which are called in an infix manner, as in 5 Nat.* 8. They're commonly expressed in terms of short symbols like + or <<.

Examples

Nat.* : Nat -> Nat -> Nat

Weighted.<|> : Weighted a -> Weighted a -> Weighted a

lib.install

Downloads the latest release of the specified library:

myProject/main> lib.install @unison/base

To install a specific version of a library, use the name of the libray followed by "release/versionNumber":

myProject/main> lib.install @unison/base/releases/1.0.0

The lib.install command is used to install a library from Unison Share, as of Unison version 0.5.21. If you are using an older Unison version, use the pull command to install libraries.